#!/usr/bin/awk -f
# Translate from RNA to sequences of amino acids and stop codons.
# We do not stop after stop codons.

# > echo agugacauguaugcuacgaugcuagcuacgugacugacgu | awk -f translate.awk
# SDMYATMLAT*LT

# Note the case sensitivity.
# If the genetic code is lower case so must your input be.
# e.g. tr A-Z a-z <sample.seq | awk -f translate.awk
# Note that the sequence must be RNA
# e.g. tr A-Z a-z <sample.seq | tr t u | awk -f translate.awk
# To try the next frame:
# sed 's/^.//' <sample.seq | tr A-Z a-z | tr t u |  awk -f translate.awk

function loadHash( theFileName, theHash ) {
  temp = $0;
  while ( 0 < ( getline < theFileName ) ) {
    theHash[$1] = $2;
  }
  $0 = temp;
}

BEGIN {
  frame = 1;
  gencodefile = "standard.genetic.code";
# UNKNOWN = "?";
}

1 == NR {
  loadHash( gencodefile, gencode );
  frame = ( ( frame - 1 ) % 3 ) + 1;
}

{
  # Add a prefix and a suffix of "n"s 
  # so that we can assume that we are always in frame 1
  # and that the last frame is complete.
  # This might allow for another amino acid to be determined
  # since a few condons starting with or ending with n might be translated.
  # In the standard genetic code there are none that start with n
  # and none that end with two ns.
  # So this is probably not very useful.
  # But it's cheap and more complete.
  source = "";
  prefixLength = frame - 1;
  while ( prefixLength-- ) source = "n" source;
  source = source $0;
  l = length( source ) % 3;
  if ( 1 == l ) {
    source = source "nn";
  }
  else if ( 2 == l ) {
    source = source "n";
  }
  srclen = length( source );
  for ( i = 1; i < srclen; i += 3 ) {
    aa = gencode[ substr( source, i, 3 ) ];
    if ( aa ) {
      printf( "%s", aa );
    }
    else if ( UNKNOWN ) {
      printf( "%s", UNKNOWN );
    }
#   else {
#     printf( "%s", gencode[ substr( source, i, 3 ) ] );
#   }
  }
  print "";
}